      SUBROUTINE DTPMV ( UPLO, TRANS, DIAG, N, AP, X, INCX )
****************************************************************************
*                                                                          *
*   DATA PARALLEL BLAS based on MPL                                        *
*                                                                          *
*   Version 1.0   1/9-92 ,                                                 *
*   For MasPar MP-1 computers                                              *
*                                                                          *
*   para//ab, University of Bergen, NORWAY                                 *
*                                                                          *
*   These programs must be called using F90 style array syntax.            *
*   Note that the F77 style calling sequence has been retained             *
*   in this version for compatibility reasons, be aware that               *
*   parameters related to the array dimensions and shape therefore may     *
*   be redundant and without any influence.                                *
*   The calling sequence may be changed in a future version.               *
*   Please report any BUGs, ideas for improvement or other                 *
*   comments to                                                            *
*                    adm@parallab.uib.no                                   *
*                                                                          *
*   Future versions may then reflect your suggestions.                     *
*   The most current version of this software is available                 *
*   from netlib@nac.no , send the message `send index from maspar'         *
*                                                                          *
*   REVISIONS:                                                             *
*                                                                          *
****************************************************************************
      implicit none
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      CHARACTER*1        DIAG, TRANS, UPLO
*     .. Array Arguments ..
      double precision, array(:) :: ap, x
      intent(inout) :: ap, x
*     ..
*
*  Purpose
*  =======
*
*  DTPMV  performs one of the matrix-vector operations
*
*     x := A*x,   or   x := A'*x,
*
*  where x is an n element vector and  A is an n by n unit, or non-unit,
*  upper or lower triangular matrix, supplied in packed form.
*
*  Parameters
*  ==========
*
*  UPLO   - CHARACTER*1.
*           On entry, UPLO specifies whether the matrix is an upper or
*           lower triangular matrix as follows:
*
*              UPLO = 'U' or 'u'   A is an upper triangular matrix.
*
*              UPLO = 'L' or 'l'   A is a lower triangular matrix.
*
*           Unchanged on exit.
*
*  TRANS  - CHARACTER*1.
*           On entry, TRANS specifies the operation to be performed as
*           follows:
*
*              TRANS = 'N' or 'n'   x := A*x.
*
*              TRANS = 'T' or 't'   x := A'*x.
*
*              TRANS = 'C' or 'c'   x := A'*x.
*
*           Unchanged on exit.
*
*  DIAG   - CHARACTER*1.
*           On entry, DIAG specifies whether or not A is unit
*           triangular as follows:
*
*              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
*
*              DIAG = 'N' or 'n'   A is not assumed to be unit
*                                  triangular.
*
*           Unchanged on exit.
*
*  N      - INTEGER.
*           On entry, N specifies the order of the matrix A.
*           N must be at least zero.
*           Unchanged on exit.
*
*  AP     - DOUBLE PRECISION array of DIMENSION at least
*           ( ( n*( n + 1 ) )/2 ).
*           Before entry with  UPLO = 'U' or 'u', the array AP must
*           contain the upper triangular matrix packed sequentially,
*           column by column, so that AP( 1 ) contains a( 1, 1 ),
*           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
*           respectively, and so on.
*           Before entry with UPLO = 'L' or 'l', the array AP must
*           contain the lower triangular matrix packed sequentially,
*           column by column, so that AP( 1 ) contains a( 1, 1 ),
*           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
*           respectively, and so on.
*           Note that when  DIAG = 'U' or 'u', the diagonal elements of
*           A are not referenced, but are assumed to be unity.
*           Unchanged on exit.
*
*  X      - DOUBLE PRECISION array of dimension at least
*           ( 1 + ( n - 1 )*abs( INCX ) ).
*           Before entry, the incremented array X must contain the n
*           element vector x. On exit, X is overwritten with the
*           tranformed vector x.
*
*  INCX   - INTEGER.
*           On entry, INCX specifies the increment for the elements of
*           X. INCX must not be zero.
*           Unchanged on exit.
*
*
*  Level 2 Blas routine.
*
*  -- Written on 22-October-1986.
*     Jack Dongarra, Argonne National Lab.
*     Jeremy Du Croz, Nag Central Office.
*     Sven Hammarling, Nag Central Office.
*     Richard Hanson, Sandia National Labs.
*
*

*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      PARAMETER        ( ZERO = 0.0D+0 )
c
c   later adjust ncutoff for most efficiency
c
      integer ncutoff
      parameter        ( ncutoff = 8 )
*     .. Local Scalars ..
      double precision               t
      INTEGER            INFO, KX, na, i, j
      LOGICAL            NOUNIT, UPPER
*     .. Local Arrays
      double precision,    array(n, n)      :: fulla
      double precision,    array(n)         :: xloc
      double precision,    array(n*(n+1)/2) :: xs
      logical, array(n*(n+1)/2) :: segpvar

*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           LSAME
*     .. External Subroutines ..
      EXTERNAL           XERBLA
      EXTERNAL           dfillo
      EXTERNAL           dpacku
      EXTERNAL           DTRMV
      EXTERNAL           degad
*     .. Intrinsic Functions ..
      INTRINSIC          spread
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      NOUNIT = LSAME( DIAG, 'N' )
      UPPER  = LSAME( UPLO, 'U' )
*
      INFO = 0
      IF     ( .NOT.UPPER              .AND.
     $         .NOT.LSAME( UPLO , 'L' )      )THEN
         INFO = 1
      ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
     $         .NOT.LSAME( TRANS, 'T' ).AND.
     $         .NOT.LSAME( TRANS, 'C' )      )THEN
         INFO = 2
      ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
     $         .NOT.LSAME( DIAG , 'N' )      )THEN
         INFO = 3
      ELSE IF( N.LT.0 )THEN
         INFO = 4
      ELSE IF( INCX.EQ.0 )THEN
         INFO = 7
      END IF
      IF( INFO.NE.0 )THEN
         CALL XERBLA( 'DTPMV ', INFO )
         RETURN
      END IF
*
*     Quick return if possible.
*
      IF( N.EQ.0 ) RETURN
*
*     Set up the start point in X if the increment is not unity. This
*     will be  ( N - 1 )*INCX  too small for descending loops.
*
      IF( INCX.LE.0 )THEN
         KX = 1 - ( N - 1 )*INCX
      ELSE IF( INCX.NE.1 )THEN
         KX = 1
      END IF
*
      if (n .le. ncutoff) then
	 call dfillo ( fulla, uplo, n, n*n, ap )
	 call dtrmv ( uplo, trans, diag, n, fulla, n, x, incx )
      else
c
c   n is > cutoff
c
         na = n * (n+1) / 2
         if( incx.eq.1 )then
	    xloc(1:n) = x(1:n)
         else
            xloc(1:n) = x(kx : kx+incx*(n-1) : incx)
         endif
c
         if (lsame(trans, 'N')) then
	   if (upper) then
	      i = 1
	      if (nounit) xloc(1) = ap(1) * xloc(1)
	      i = i + 1
	      do j = 2, n
	         if (nounit) then
	            t = xloc(j)
	            xloc(j) = zero
	            xloc(1:j) = xloc(1:j) + ap(i:i+j) * t
	         else
	            xloc(1:j-1)=xloc(1:j-1)+ap(i:i+j-1)*xloc(j)
	         endif
	         i = i + j
	      enddo
	   else
	      i = n * (n + 1) / 2
	      if (nounit) xloc(n) = ap(i) * xloc(n)
	      i = i - 2
	      do j = n-1, 1, -1
	         if (nounit) then
	            t = xloc(j)
	            xloc(j) = zero
	            xloc(j:n) = xloc(j:n) + ap(i:i+(n-j)) * t
	         else
	            xloc(j+1:n)=xloc(j+1:n)+ap(i+1:i+(n-j))*xloc(j)
	         endif
	         i = i - (n - j + 2)
	      enddo
	   endif
         else
c
c   code for a' * x
c
	   if (upper) then
	     if (nounit) then
	        call dpacku(xs, uplo, n, na, spread(xloc,2,n))
	        xs = xs * ap
	        segpvar(1:na) = .false.
clater	        forall (j=1:n) segpvar(j * (j+1) / 2) = .true.
		do j = 1, n
		segpvar(j * (j+1) / 2) = .true.
		enddo
clater	        xs = degaddscan(xs, na, segpvar, 'R' )
	        call degad ( xs, xs, na, segpvar, 'R' )
clater	        forall (j = 1:n) xloc(j) = xs( j * (j+1) / 2 )
		do j = 1, n
	        xloc(j) = xs( j * (j+1) / 2 )
		enddo
	     else
	        call dpacku(xs, uplo, n, na, spread(xloc,2,n))
	        segpvar(1:na) = .false.
clater	        forall (j=1:n) segpvar(j * (j+1) / 2) = .true.
		do j = 1, n
		segpvar(j * (j+1) / 2) = .true.
		enddo
	        where (.not. segpvar) xs = xs * ap
clater	        xs = degaddscan(xs, na, segpvar, 'R')
	        call degad ( xs, xs, na, segpvar, 'R' )
clater	        forall (j = 1:n) xloc(j) = xs( j * (j+1) / 2 )
		do j = 1, n
	        xloc(j) = xs( j * (j+1) / 2 )
		enddo
	     endif
	   else
	     if (nounit) then
	        call dpacku(xs, uplo, n, na, spread(xloc,2,n))
	        xs = xs * ap
	        segpvar(1:na) = .false.
clater	        forall (j=1:n) segpvar(j * (j+1) / 2) = .true.
		do j = 1, n
		segpvar((na+1) - j * (j+1) / 2) = .true.
		enddo
clater	        xs = degaddscan(xs, na, segpvar, 'L')
	        call degad ( xs, xs, na, segpvar, 'L' )
clater	        forall (j = 1:n) xloc(n+1-j) = xs( (na+1) - j * (j+1) / 2 )
		do j = 1, n
	        xloc(n+1-j) = xs( (na+1) - j * (j+1) / 2 )
		enddo
	     else
	        call dpacku(xs, uplo, n, na, spread(xloc,2,n))
	        segpvar(1:na) = .false.
clater	        forall (j=1:n) segpvar((na+1) - j * (j+1) / 2) = .true.
		do j = 1, n
		segpvar((na+1) - j * (j+1) / 2) = .true.
		enddo
	        where (.not. segpvar ) xs = xs * ap
clater	        xs = degaddscan(xs, na, segpvar, 'L')
	        call degad ( xs, xs, na, segpvar, 'L' )
clater	        forall (j = 1:n) xloc(n+1-j) = xs( (na+1) - j * (j+1) / 2 )
		do j = 1, n
	        xloc(n+1-j) = xs( (na+1) - j * (j+1) / 2 )
 		enddo
	     endif
	   endif
         endif
c
         if( incx.eq.1 )then
	     x(1:n) = xloc
         else
             x(kx : kx+incx*(n-1) : incx) = xloc
         endif
      endif
*
      RETURN
*
*     End of DTPMV .
*
      END