<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">#
# Data/Dumper.pm
#
# convert perl data structures into perl syntax suitable for both printing
# and eval
#
# Documentation at the __END__
#

package Data::Dumper;

$VERSION = '2.102';

#$| = 1;

require 5.005_64;
require Exporter;
use XSLoader ();
require overload;

use Carp;

@ISA = qw(Exporter);
@EXPORT = qw(Dumper);
@EXPORT_OK = qw(DumperX);

XSLoader::load 'Data::Dumper';

# module vars and their defaults
$Indent = 2 unless defined $Indent;
$Purity = 0 unless defined $Purity;
$Pad = "" unless defined $Pad;
$Varname = "VAR" unless defined $Varname;
$Useqq = 0 unless defined $Useqq;
$Terse = 0 unless defined $Terse;
$Freezer = "" unless defined $Freezer;
$Toaster = "" unless defined $Toaster;
$Deepcopy = 0 unless defined $Deepcopy;
$Quotekeys = 1 unless defined $Quotekeys;
$Bless = "bless" unless defined $Bless;
#$Expdepth = 0 unless defined $Expdepth;
$Maxdepth = 0 unless defined $Maxdepth;

#
# expects an arrayref of values to be dumped.
# can optionally pass an arrayref of names for the values.
# names must have leading $ sign stripped. begin the name with *
# to cause output of arrays and hashes rather than refs.
#
sub new {
  my($c, $v, $n) = @_;

  croak "Usage:  PACKAGE-&gt;new(ARRAYREF, [ARRAYREF])" 
    unless (defined($v) &amp;&amp; (ref($v) eq 'ARRAY'));
  $n = [] unless (defined($n) &amp;&amp; (ref($v) eq 'ARRAY'));

  my($s) = { 
             level      =&gt; 0,           # current recursive depth
	     indent     =&gt; $Indent,     # various styles of indenting
	     pad	=&gt; $Pad,        # all lines prefixed by this string
	     xpad       =&gt; "",          # padding-per-level
	     apad       =&gt; "",          # added padding for hash keys n such
	     sep        =&gt; "",          # list separator
	     seen       =&gt; {},          # local (nested) refs (id =&gt; [name, val])
	     todump     =&gt; $v,          # values to dump []
	     names      =&gt; $n,          # optional names for values []
	     varname    =&gt; $Varname,    # prefix to use for tagging nameless ones
             purity     =&gt; $Purity,     # degree to which output is evalable
             useqq 	=&gt; $Useqq,      # use "" for strings (backslashitis ensues)
             terse 	=&gt; $Terse,      # avoid name output (where feasible)
             freezer	=&gt; $Freezer,    # name of Freezer method for objects
             toaster	=&gt; $Toaster,    # name of method to revive objects
             deepcopy	=&gt; $Deepcopy,   # dont cross-ref, except to stop recursion
             quotekeys	=&gt; $Quotekeys,  # quote hash keys
             'bless'	=&gt; $Bless,	# keyword to use for "bless"
#	     expdepth   =&gt; $Expdepth,   # cutoff depth for explicit dumping
	     maxdepth	=&gt; $Maxdepth,   # depth beyond which we give up
	   };

  if ($Indent &gt; 0) {
    $s-&gt;{xpad} = "  ";
    $s-&gt;{sep} = "\n";
  }
  return bless($s, $c);
}

#
# add-to or query the table of already seen references
#
sub Seen {
  my($s, $g) = @_;
  if (defined($g) &amp;&amp; (ref($g) eq 'HASH'))  {
    my($k, $v, $id);
    while (($k, $v) = each %$g) {
      if (defined $v and ref $v) {
	($id) = (overload::StrVal($v) =~ /\((.*)\)$/);
	if ($k =~ /^[*](.*)$/) {
	  $k = (ref $v eq 'ARRAY') ? ( "\\\@" . $1 ) :
	       (ref $v eq 'HASH')  ? ( "\\\%" . $1 ) :
	       (ref $v eq 'CODE')  ? ( "\\\&amp;" . $1 ) :
				     (   "\$" . $1 ) ;
	}
	elsif ($k !~ /^\$/) {
	  $k = "\$" . $k;
	}
	$s-&gt;{seen}{$id} = [$k, $v];
      }
      else {
	carp "Only refs supported, ignoring non-ref item \$$k";
      }
    }
    return $s;
  }
  else {
    return map { @$_ } values %{$s-&gt;{seen}};
  }
}

#
# set or query the values to be dumped
#
sub Values {
  my($s, $v) = @_;
  if (defined($v) &amp;&amp; (ref($v) eq 'ARRAY'))  {
    $s-&gt;{todump} = [@$v];        # make a copy
    return $s;
  }
  else {
    return @{$s-&gt;{todump}};
  }
}

#
# set or query the names of the values to be dumped
#
sub Names {
  my($s, $n) = @_;
  if (defined($n) &amp;&amp; (ref($n) eq 'ARRAY'))  {
    $s-&gt;{names} = [@$n];         # make a copy
    return $s;
  }
  else {
    return @{$s-&gt;{names}};
  }
}

sub DESTROY {}

sub Dump {
    return &amp;Dumpxs
	unless $Data::Dumper::Useqq || (ref($_[0]) &amp;&amp; $_[0]-&gt;{useqq});
    return &amp;Dumpperl;
}

#
# dump the refs in the current dumper object.
# expects same args as new() if called via package name.
#
sub Dumpperl {
  my($s) = shift;
  my(@out, $val, $name);
  my($i) = 0;
  local(@post);

  $s = $s-&gt;new(@_) unless ref $s;

  for $val (@{$s-&gt;{todump}}) {
    my $out = "";
    @post = ();
    $name = $s-&gt;{names}[$i++];
    if (defined $name) {
      if ($name =~ /^[*](.*)$/) {
	if (defined $val) {
	  $name = (ref $val eq 'ARRAY') ? ( "\@" . $1 ) :
		  (ref $val eq 'HASH')  ? ( "\%" . $1 ) :
		  (ref $val eq 'CODE')  ? ( "\*" . $1 ) :
					  ( "\$" . $1 ) ;
	}
	else {
	  $name = "\$" . $1;
	}
      }
      elsif ($name !~ /^\$/) {
	$name = "\$" . $name;
      }
    }
    else {
      $name = "\$" . $s-&gt;{varname} . $i;
    }

    my $valstr;
    {
      local($s-&gt;{apad}) = $s-&gt;{apad};
      $s-&gt;{apad} .= ' ' x (length($name) + 3) if $s-&gt;{indent} &gt;= 2;
      $valstr = $s-&gt;_dump($val, $name);
    }

    $valstr = "$name = " . $valstr . ';' if @post or !$s-&gt;{terse};
    $out .= $s-&gt;{pad} . $valstr . $s-&gt;{sep};
    $out .= $s-&gt;{pad} . join(';' . $s-&gt;{sep} . $s-&gt;{pad}, @post) 
      . ';' . $s-&gt;{sep} if @post;

    push @out, $out;
  }
  return wantarray ? @out : join('', @out);
}

#
# twist, toil and turn;
# and recurse, of course.
#
sub _dump {
  my($s, $val, $name) = @_;
  my($sname);
  my($out, $realpack, $realtype, $type, $ipad, $id, $blesspad);

  $type = ref $val;
  $out = "";

  if ($type) {

    # prep it, if it looks like an object
    if (my $freezer = $s-&gt;{freezer}) {
      $val-&gt;$freezer() if UNIVERSAL::can($val, $freezer);
    }

    ($realpack, $realtype, $id) =
      (overload::StrVal($val) =~ /^(?:(.*)\=)?([^=]*)\(([^\(]*)\)$/);

    # if it has a name, we need to either look it up, or keep a tab
    # on it so we know when we hit it later
    if (defined($name) and length($name)) {
      # keep a tab on it so that we dont fall into recursive pit
      if (exists $s-&gt;{seen}{$id}) {
#	if ($s-&gt;{expdepth} &lt; $s-&gt;{level}) {
	  if ($s-&gt;{purity} and $s-&gt;{level} &gt; 0) {
	    $out = ($realtype eq 'HASH')  ? '{}' :
	      ($realtype eq 'ARRAY') ? '[]' :
		'do{my $o}' ;
	    push @post, $name . " = " . $s-&gt;{seen}{$id}[0];
	  }
	  else {
	    $out = $s-&gt;{seen}{$id}[0];
	    if ($name =~ /^([\@\%])/) {
	      my $start = $1;
	      if ($out =~ /^\\$start/) {
		$out = substr($out, 1);
	      }
	      else {
		$out = $start . '{' . $out . '}';
	      }
	    }
          }
	  return $out;
#        }
      }
      else {
        # store our name
        $s-&gt;{seen}{$id} = [ (($name =~ /^[@%]/)     ? ('\\' . $name ) :
			     ($realtype eq 'CODE' and
			      $name =~ /^[*](.*)$/) ? ('\\&amp;' . $1 )   :
			     $name          ),
			    $val ];
      }
    }

    if ($realpack and $realpack eq 'Regexp') {
	$out = "$val";
	$out =~ s,/,\\/,g;
	return "qr/$out/";
    }

    # If purity is not set and maxdepth is set, then check depth: 
    # if we have reached maximum depth, return the string
    # representation of the thing we are currently examining
    # at this depth (i.e., 'Foo=ARRAY(0xdeadbeef)'). 
    if (!$s-&gt;{purity}
	and $s-&gt;{maxdepth} &gt; 0
	and $s-&gt;{level} &gt;= $s-&gt;{maxdepth})
    {
      return qq['$val'];
    }

    # we have a blessed ref
    if ($realpack) {
      $out = $s-&gt;{'bless'} . '( ';
      $blesspad = $s-&gt;{apad};
      $s-&gt;{apad} .= '       ' if ($s-&gt;{indent} &gt;= 2);
    }

    $s-&gt;{level}++;
    $ipad = $s-&gt;{xpad} x $s-&gt;{level};

    if ($realtype eq 'SCALAR' || $realtype eq 'REF') {
      if ($realpack) {
	$out .= 'do{\\(my $o = ' . $s-&gt;_dump($$val, "\${$name}") . ')}';
      }
      else {
	$out .= '\\' . $s-&gt;_dump($$val, "\${$name}");
      }
    }
    elsif ($realtype eq 'GLOB') {
	$out .= '\\' . $s-&gt;_dump($$val, "*{$name}");
    }
    elsif ($realtype eq 'ARRAY') {
      my($v, $pad, $mname);
      my($i) = 0;
      $out .= ($name =~ /^\@/) ? '(' : '[';
      $pad = $s-&gt;{sep} . $s-&gt;{pad} . $s-&gt;{apad};
      ($name =~ /^\@(.*)$/) ? ($mname = "\$" . $1) : 
	# omit -&gt; if $foo-&gt;[0]-&gt;{bar}, but not ${$foo-&gt;[0]}-&gt;{bar}
	($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
	  ($mname = $name . '-&gt;');
      $mname .= '-&gt;' if $mname =~ /^\*.+\{[A-Z]+\}$/;
      for $v (@$val) {
	$sname = $mname . '[' . $i . ']';
	$out .= $pad . $ipad . '#' . $i if $s-&gt;{indent} &gt;= 3;
	$out .= $pad . $ipad . $s-&gt;_dump($v, $sname);
	$out .= "," if $i++ &lt; $#$val;
      }
      $out .= $pad . ($s-&gt;{xpad} x ($s-&gt;{level} - 1)) if $i;
      $out .= ($name =~ /^\@/) ? ')' : ']';
    }
    elsif ($realtype eq 'HASH') {
      my($k, $v, $pad, $lpad, $mname);
      $out .= ($name =~ /^\%/) ? '(' : '{';
      $pad = $s-&gt;{sep} . $s-&gt;{pad} . $s-&gt;{apad};
      $lpad = $s-&gt;{apad};
      ($name =~ /^\%(.*)$/) ? ($mname = "\$" . $1) :
	# omit -&gt; if $foo-&gt;[0]-&gt;{bar}, but not ${$foo-&gt;[0]}-&gt;{bar}
	($name =~ /^\\?[\%\@\*\$][^{].*[]}]$/) ? ($mname = $name) :
	  ($mname = $name . '-&gt;');
      $mname .= '-&gt;' if $mname =~ /^\*.+\{[A-Z]+\}$/;
      while (($k, $v) = each %$val) {
	my $nk = $s-&gt;_dump($k, "");
	$nk = $1 if !$s-&gt;{quotekeys} and $nk =~ /^[\"\']([A-Za-z_]\w*)[\"\']$/;
	$sname = $mname . '{' . $nk . '}';
	$out .= $pad . $ipad . $nk . " =&gt; ";

	# temporarily alter apad
	$s-&gt;{apad} .= (" " x (length($nk) + 4)) if $s-&gt;{indent} &gt;= 2;
	$out .= $s-&gt;_dump($val-&gt;{$k}, $sname) . ",";
	$s-&gt;{apad} = $lpad if $s-&gt;{indent} &gt;= 2;
      }
      if (substr($out, -1) eq ',') {
	chop $out;
	$out .= $pad . ($s-&gt;{xpad} x ($s-&gt;{level} - 1));
      }
      $out .= ($name =~ /^\%/) ? ')' : '}';
    }
    elsif ($realtype eq 'CODE') {
      $out .= 'sub { "DUMMY" }';
      carp "Encountered CODE ref, using dummy placeholder" if $s-&gt;{purity};
    }
    else {
      croak "Can\'t handle $realtype type.";
    }
    
    if ($realpack) { # we have a blessed ref
      $out .= ', \'' . $realpack . '\'' . ' )';
      $out .= '-&gt;' . $s-&gt;{toaster} . '()'  if $s-&gt;{toaster} ne '';
      $s-&gt;{apad} = $blesspad;
    }
    $s-&gt;{level}--;

  }
  else {                                 # simple scalar

    my $ref = \$_[1];
    # first, catalog the scalar
    if ($name ne '') {
      ($id) = ("$ref" =~ /\(([^\(]*)\)$/);
      if (exists $s-&gt;{seen}{$id}) {
        if ($s-&gt;{seen}{$id}[2]) {
	  $out = $s-&gt;{seen}{$id}[0];
	  #warn "[&lt;$out]\n";
	  return "\${$out}";
	}
      }
      else {
	#warn "[&gt;\\$name]\n";
	$s-&gt;{seen}{$id} = ["\\$name", $ref];
      }
    }
    if (ref($ref) eq 'GLOB' or "$ref" =~ /=GLOB\([^()]+\)$/) {  # glob
      my $name = substr($val, 1);
      if ($name =~ /^[A-Za-z_][\w:]*$/) {
	$name =~ s/^main::/::/;
	$sname = $name;
      }
      else {
	$sname = $s-&gt;_dump($name, "");
	$sname = '{' . $sname . '}';
      }
      if ($s-&gt;{purity}) {
	my $k;
	local ($s-&gt;{level}) = 0;
	for $k (qw(SCALAR ARRAY HASH)) {
	  my $gval = *$val{$k};
	  next unless defined $gval;
	  next if $k eq "SCALAR" &amp;&amp; ! defined $$gval;  # always there

	  # _dump can push into @post, so we hold our place using $postlen
	  my $postlen = scalar @post;
	  $post[$postlen] = "\*$sname = ";
	  local ($s-&gt;{apad}) = " " x length($post[$postlen]) if $s-&gt;{indent} &gt;= 2;
	  $post[$postlen] .= $s-&gt;_dump($gval, "\*$sname\{$k\}");
	}
      }
      $out .= '*' . $sname;
    }
    elsif (!defined($val)) {
      $out .= "undef";
    }
    elsif ($val =~ /^(?:0|-?[1-9]\d{0,8})$/) { # safe decimal number
      $out .= $val;
    }
    else {				 # string
      if ($s-&gt;{useqq}) {
	$out .= qquote($val, $s-&gt;{useqq});
      }
      else {
	$val =~ s/([\\\'])/\\$1/g;
	$out .= '\'' . $val .  '\'';
      }
    }
  }
  if ($id) {
    # if we made it this far, $id was added to seen list at current
    # level, so remove it to get deep copies
    if ($s-&gt;{deepcopy}) {
      delete($s-&gt;{seen}{$id});
    }
    elsif ($name) {
      $s-&gt;{seen}{$id}[2] = 1;
    }
  }
  return $out;
}
  
#
# non-OO style of earlier version
#
sub Dumper {
  return Data::Dumper-&gt;Dump([@_]);
}

# compat stub
sub DumperX {
  return Data::Dumper-&gt;Dumpxs([@_], []);
}

sub Dumpf { return Data::Dumper-&gt;Dump(@_) }

sub Dumpp { print Data::Dumper-&gt;Dump(@_) }

#
# reset the "seen" cache 
#
sub Reset {
  my($s) = shift;
  $s-&gt;{seen} = {};
  return $s;
}

sub Indent {
  my($s, $v) = @_;
  if (defined($v)) {
    if ($v == 0) {
      $s-&gt;{xpad} = "";
      $s-&gt;{sep} = "";
    }
    else {
      $s-&gt;{xpad} = "  ";
      $s-&gt;{sep} = "\n";
    }
    $s-&gt;{indent} = $v;
    return $s;
  }
  else {
    return $s-&gt;{indent};
  }
}

sub Pad {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{pad} = $v), return $s) : $s-&gt;{pad};
}

sub Varname {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{varname} = $v), return $s) : $s-&gt;{varname};
}

sub Purity {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{purity} = $v), return $s) : $s-&gt;{purity};
}

sub Useqq {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{useqq} = $v), return $s) : $s-&gt;{useqq};
}

sub Terse {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{terse} = $v), return $s) : $s-&gt;{terse};
}

sub Freezer {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{freezer} = $v), return $s) : $s-&gt;{freezer};
}

sub Toaster {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{toaster} = $v), return $s) : $s-&gt;{toaster};
}

sub Deepcopy {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{deepcopy} = $v), return $s) : $s-&gt;{deepcopy};
}

sub Quotekeys {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{quotekeys} = $v), return $s) : $s-&gt;{quotekeys};
}

sub Bless {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{'bless'} = $v), return $s) : $s-&gt;{'bless'};
}

sub Maxdepth {
  my($s, $v) = @_;
  defined($v) ? (($s-&gt;{'maxdepth'} = $v), return $s) : $s-&gt;{'maxdepth'};
}


# used by qquote below
my %esc = (  
    "\a" =&gt; "\\a",
    "\b" =&gt; "\\b",
    "\t" =&gt; "\\t",
    "\n" =&gt; "\\n",
    "\f" =&gt; "\\f",
    "\r" =&gt; "\\r",
    "\e" =&gt; "\\e",
);

# put a string value in double quotes
sub qquote {
  local($_) = shift;
  s/([\\\"\@\$])/\\$1/g;
  return qq("$_") unless 
    /[^ !"\#\$%&amp;'()*+,\-.\/0-9:;&lt;=&gt;?\@A-Z[\\\]^_`a-z{|}~]/;  # fast exit

  my $high = shift || "";
  s/([\a\b\t\n\f\r\e])/$esc{$1}/g;

  if (ord('^')==94)  { # ascii
    # no need for 3 digits in escape for these
    s/([\0-\037])(?!\d)/'\\'.sprintf('%o',ord($1))/eg;
    s/([\0-\037\177])/'\\'.sprintf('%03o',ord($1))/eg;
    # all but last branch below not supported --BEHAVIOR SUBJECT TO CHANGE--
    if ($high eq "iso8859") {
      s/([\200-\240])/'\\'.sprintf('%o',ord($1))/eg;
    } elsif ($high eq "utf8") {
#     use utf8;
#     $str =~ s/([^\040-\176])/sprintf "\\x{%04x}", ord($1)/ge;
    } elsif ($high eq "8bit") {
        # leave it as it is
    } else {
      s/([\200-\377])/'\\'.sprintf('%03o',ord($1))/eg;
    }
  }
  else { # ebcdic
      s{([^ !"\#\$%&amp;'()*+,\-.\/0-9:;&lt;=&gt;?\@A-Z[\\\]^_`a-z{|}~])(?!\d)}
       {my $v = ord($1); '\\'.sprintf(($v &lt;= 037 ? '%o' : '%03o'), $v)}eg;
      s{([^ !"\#\$%&amp;'()*+,\-.\/0-9:;&lt;=&gt;?\@A-Z[\\\]^_`a-z{|}~])}
       {'\\'.sprintf('%03o',ord($1))}eg;
  }

  return qq("$_");
}

1;
__END__

=head1 NAME

Data::Dumper - stringified perl data structures, suitable for both printing and C&lt;eval&gt;


=head1 SYNOPSIS

    use Data::Dumper;

    # simple procedural interface
    print Dumper($foo, $bar);

    # extended usage with names
    print Data::Dumper-&gt;Dump([$foo, $bar], [qw(foo *ary)]);

    # configuration variables
    {
      local $Data::Dump::Purity = 1;
      eval Data::Dumper-&gt;Dump([$foo, $bar], [qw(foo *ary)]);
    }

    # OO usage
    $d = Data::Dumper-&gt;new([$foo, $bar], [qw(foo *ary)]);
       ...
    print $d-&gt;Dump;
       ...
    $d-&gt;Purity(1)-&gt;Terse(1)-&gt;Deepcopy(1);
    eval $d-&gt;Dump;


=head1 DESCRIPTION

Given a list of scalars or reference variables, writes out their contents in
perl syntax. The references can also be objects.  The contents of each
variable is output in a single Perl statement.  Handles self-referential
structures correctly.

The return value can be C&lt;eval&gt;ed to get back an identical copy of the
original reference structure.

Any references that are the same as one of those passed in will be named
C&lt;$VAR&gt;I&lt;n&gt; (where I&lt;n&gt; is a numeric suffix), and other duplicate references
to substructures within C&lt;$VAR&gt;I&lt;n&gt; will be appropriately labeled using arrow
notation.  You can specify names for individual values to be dumped if you
use the C&lt;Dump()&gt; method, or you can change the default C&lt;$VAR&gt; prefix to
something else.  See C&lt;$Data::Dumper::Varname&gt; and C&lt;$Data::Dumper::Terse&gt;
below.

The default output of self-referential structures can be C&lt;eval&gt;ed, but the
nested references to C&lt;$VAR&gt;I&lt;n&gt; will be undefined, since a recursive
structure cannot be constructed using one Perl statement.  You should set the
C&lt;Purity&gt; flag to 1 to get additional statements that will correctly fill in
these references.

In the extended usage form, the references to be dumped can be given
user-specified names.  If a name begins with a C&lt;*&gt;, the output will 
describe the dereferenced type of the supplied reference for hashes and
arrays, and coderefs.  Output of names will be avoided where possible if
the C&lt;Terse&gt; flag is set.

In many cases, methods that are used to set the internal state of the
object will return the object itself, so method calls can be conveniently
chained together.

Several styles of output are possible, all controlled by setting
the C&lt;Indent&gt; flag.  See L&lt;Configuration Variables or Methods&gt; below 
for details.


=head2 Methods

=over 4

=item I&lt;PACKAGE&gt;-&gt;new(I&lt;ARRAYREF [&gt;, I&lt;ARRAYREF]&gt;)

Returns a newly created C&lt;Data::Dumper&gt; object.  The first argument is an
anonymous array of values to be dumped.  The optional second argument is an
anonymous array of names for the values.  The names need not have a leading
C&lt;$&gt; sign, and must be comprised of alphanumeric characters.  You can begin
a name with a C&lt;*&gt; to specify that the dereferenced type must be dumped
instead of the reference itself, for ARRAY and HASH references.

The prefix specified by C&lt;$Data::Dumper::Varname&gt; will be used with a
numeric suffix if the name for a value is undefined.

Data::Dumper will catalog all references encountered while dumping the
values. Cross-references (in the form of names of substructures in perl
syntax) will be inserted at all possible points, preserving any structural
interdependencies in the original set of values.  Structure traversal is
depth-first,  and proceeds in order from the first supplied value to
the last.

=item I&lt;$OBJ&gt;-&gt;Dump  I&lt;or&gt;  I&lt;PACKAGE&gt;-&gt;Dump(I&lt;ARRAYREF [&gt;, I&lt;ARRAYREF]&gt;)

Returns the stringified form of the values stored in the object (preserving
the order in which they were supplied to C&lt;new&gt;), subject to the
configuration options below.  In a list context, it returns a list
of strings corresponding to the supplied values.

The second form, for convenience, simply calls the C&lt;new&gt; method on its
arguments before dumping the object immediately.

=item I&lt;$OBJ&gt;-&gt;Seen(I&lt;[HASHREF]&gt;)

Queries or adds to the internal table of already encountered references.
You must use C&lt;Reset&gt; to explicitly clear the table if needed.  Such
references are not dumped; instead, their names are inserted wherever they
are encountered subsequently.  This is useful especially for properly
dumping subroutine references.

Expects a anonymous hash of name =&gt; value pairs.  Same rules apply for names
as in C&lt;new&gt;.  If no argument is supplied, will return the "seen" list of
name =&gt; value pairs, in a list context.  Otherwise, returns the object
itself.

=item I&lt;$OBJ&gt;-&gt;Values(I&lt;[ARRAYREF]&gt;)

Queries or replaces the internal array of values that will be dumped.
When called without arguments, returns the values.  Otherwise, returns the
object itself.

=item I&lt;$OBJ&gt;-&gt;Names(I&lt;[ARRAYREF]&gt;)

Queries or replaces the internal array of user supplied names for the values
that will be dumped.  When called without arguments, returns the names.
Otherwise, returns the object itself.

=item I&lt;$OBJ&gt;-&gt;Reset

Clears the internal table of "seen" references and returns the object
itself.

=back

=head2 Functions

=over 4

=item Dumper(I&lt;LIST&gt;)

Returns the stringified form of the values in the list, subject to the
configuration options below.  The values will be named C&lt;$VAR&gt;I&lt;n&gt; in the
output, where I&lt;n&gt; is a numeric suffix.  Will return a list of strings
in a list context.

=back

=head2 Configuration Variables or Methods

Several configuration variables can be used to control the kind of output
generated when using the procedural interface.  These variables are usually
C&lt;local&gt;ized in a block so that other parts of the code are not affected by
the change.  

These variables determine the default state of the object created by calling
the C&lt;new&gt; method, but cannot be used to alter the state of the object
thereafter.  The equivalent method names should be used instead to query
or set the internal state of the object.

The method forms return the object itself when called with arguments,
so that they can be chained together nicely.

=over 4

=item $Data::Dumper::Indent  I&lt;or&gt;  I&lt;$OBJ&gt;-&gt;Indent(I&lt;[NEWVAL]&gt;)

Controls the style of indentation.  It can be set to 0, 1, 2 or 3.  Style 0
spews output without any newlines, indentation, or spaces between list
items.  It is the most compact format possible that can still be called
valid perl.  Style 1 outputs a readable form with newlines but no fancy
indentation (each level in the structure is simply indented by a fixed
amount of whitespace).  Style 2 (the default) outputs a very readable form
which takes into account the length of hash keys (so the hash value lines
up).  Style 3 is like style 2, but also annotates the elements of arrays
with their index (but the comment is on its own line, so array output
consumes twice the number of lines).  Style 2 is the default.

=item $Data::Dumper::Purity  I&lt;or&gt;  I&lt;$OBJ&gt;-&gt;Purity(I&lt;[NEWVAL]&gt;)

Controls the degree to which the output can be C&lt;eval&gt;ed to recreate the
supplied reference structures.  Setting it to 1 will output additional perl
statements that will correctly recreate nested references.  The default is
0.

=item $Data::Dumper::Pad  I&lt;or&gt;  I&lt;$OBJ&gt;-&gt;Pad(I&lt;[NEWVAL]&gt;)

Specifies the string that will be prefixed to every line of the output.
Empty string by default.

=item $Data::Dumper::Varname  I&lt;or&gt;  I&lt;$OBJ&gt;-&gt;Varname(I&lt;[NEWVAL]&gt;)

Contains the prefix to use for tagging variable names in the output. The
default is "VAR".

=item $Data::Dumper::Useqq  I&lt;or&gt;  I&lt;$OBJ&gt;-&gt;Useqq(I&lt;[NEWVAL]&gt;)

When set, enables the use of double quotes for representing string values.
Whitespace other than space will be represented as C&lt;[\n\t\r]&gt;, "unsafe"
characters will be backslashed, and unprintable characters will be output as
quoted octal integers.  Since setting this variable imposes a performance
penalty, the default is 0.  C&lt;Dump()&gt; will run slower if this flag is set,
since the fast XSUB implementation doesn't support it yet.

=item $Data::Dumper::Terse  I&lt;or&gt;  I&lt;$OBJ&gt;-&gt;Terse(I&lt;[NEWVAL]&gt;)

When set, Data::Dumper will emit single, non-self-referential values as
atoms/terms rather than statements.  This means that the C&lt;$VAR&gt;I&lt;n&gt; names
will be avoided where possible, but be advised that such output may not
always be parseable by C&lt;eval&gt;.

=item $Data::Dumper::Freezer  I&lt;or&gt;  $I&lt;OBJ&gt;-&gt;Freezer(I&lt;[NEWVAL]&gt;)

Can be set to a method name, or to an empty string to disable the feature.
Data::Dumper will invoke that method via the object before attempting to
stringify it.  This method can alter the contents of the object (if, for
instance, it contains data allocated from C), and even rebless it in a
different package.  The client is responsible for making sure the specified
method can be called via the object, and that the object ends up containing
only perl data types after the method has been called.  Defaults to an empty
string.

=item $Data::Dumper::Toaster  I&lt;or&gt;  $I&lt;OBJ&gt;-&gt;Toaster(I&lt;[NEWVAL]&gt;)

Can be set to a method name, or to an empty string to disable the feature.
Data::Dumper will emit a method call for any objects that are to be dumped
using the syntax C&lt;bless(DATA, CLASS)-&gt;METHOD()&gt;.  Note that this means that
the method specified will have to perform any modifications required on the
object (like creating new state within it, and/or reblessing it in a
different package) and then return it.  The client is responsible for making
sure the method can be called via the object, and that it returns a valid
object.  Defaults to an empty string.

=item $Data::Dumper::Deepcopy  I&lt;or&gt;  $I&lt;OBJ&gt;-&gt;Deepcopy(I&lt;[NEWVAL]&gt;)

Can be set to a boolean value to enable deep copies of structures.
Cross-referencing will then only be done when absolutely essential
(i.e., to break reference cycles).  Default is 0.

=item $Data::Dumper::Quotekeys  I&lt;or&gt;  $I&lt;OBJ&gt;-&gt;Quotekeys(I&lt;[NEWVAL]&gt;)

Can be set to a boolean value to control whether hash keys are quoted.
A false value will avoid quoting hash keys when it looks like a simple
string.  Default is 1, which will always enclose hash keys in quotes.

=item $Data::Dumper::Bless  I&lt;or&gt;  $I&lt;OBJ&gt;-&gt;Bless(I&lt;[NEWVAL]&gt;)

Can be set to a string that specifies an alternative to the C&lt;bless&gt;
builtin operator used to create objects.  A function with the specified
name should exist, and should accept the same arguments as the builtin.
Default is C&lt;bless&gt;.

=item $Data::Dumper::Maxdepth  I&lt;or&gt;  $I&lt;OBJ&gt;-&gt;Maxdepth(I&lt;[NEWVAL]&gt;)

Can be set to a positive integer that specifies the depth beyond which
which we don't venture into a structure.  Has no effect when
C&lt;Data::Dumper::Purity&gt; is set.  (Useful in debugger when we often don't
want to see more than enough).  Default is 0, which means there is 
no maximum depth. 

=back

=head2 Exports

=over 4

=item Dumper

=back

=head1 EXAMPLES

Run these code snippets to get a quick feel for the behavior of this
module.  When you are through with these examples, you may want to
add or change the various configuration variables described above,
to see their behavior.  (See the testsuite in the Data::Dumper
distribution for more examples.)


    use Data::Dumper;

    package Foo;
    sub new {bless {'a' =&gt; 1, 'b' =&gt; sub { return "foo" }}, $_[0]};

    package Fuz;                       # a weird REF-REF-SCALAR object
    sub new {bless \($_ = \ 'fu\'z'), $_[0]};

    package main;
    $foo = Foo-&gt;new;
    $fuz = Fuz-&gt;new;
    $boo = [ 1, [], "abcd", \*foo,
             {1 =&gt; 'a', 023 =&gt; 'b', 0x45 =&gt; 'c'}, 
             \\"p\q\'r", $foo, $fuz];

    ########
    # simple usage
    ########

    $bar = eval(Dumper($boo));
    print($@) if $@;
    print Dumper($boo), Dumper($bar);  # pretty print (no array indices)

    $Data::Dumper::Terse = 1;          # don't output names where feasible
    $Data::Dumper::Indent = 0;         # turn off all pretty print
    print Dumper($boo), "\n";

    $Data::Dumper::Indent = 1;         # mild pretty print
    print Dumper($boo);

    $Data::Dumper::Indent = 3;         # pretty print with array indices
    print Dumper($boo);

    $Data::Dumper::Useqq = 1;          # print strings in double quotes
    print Dumper($boo);


    ########
    # recursive structures
    ########

    @c = ('c');
    $c = \@c;
    $b = {};
    $a = [1, $b, $c];
    $b-&gt;{a} = $a;
    $b-&gt;{b} = $a-&gt;[1];
    $b-&gt;{c} = $a-&gt;[2];
    print Data::Dumper-&gt;Dump([$a,$b,$c], [qw(a b c)]);


    $Data::Dumper::Purity = 1;         # fill in the holes for eval
    print Data::Dumper-&gt;Dump([$a, $b], [qw(*a b)]); # print as @a
    print Data::Dumper-&gt;Dump([$b, $a], [qw(*b a)]); # print as %b


    $Data::Dumper::Deepcopy = 1;       # avoid cross-refs
    print Data::Dumper-&gt;Dump([$b, $a], [qw(*b a)]);


    $Data::Dumper::Purity = 0;         # avoid cross-refs
    print Data::Dumper-&gt;Dump([$b, $a], [qw(*b a)]);

    ########
    # deep structures
    ########

    $a = "pearl";
    $b = [ $a ];
    $c = { 'b' =&gt; $b };
    $d = [ $c ];
    $e = { 'd' =&gt; $d };
    $f = { 'e' =&gt; $e };
    print Data::Dumper-&gt;Dump([$f], [qw(f)]);

    $Data::Dumper::Maxdepth = 3;       # no deeper than 3 refs down
    print Data::Dumper-&gt;Dump([$f], [qw(f)]);


    ########
    # object-oriented usage
    ########

    $d = Data::Dumper-&gt;new([$a,$b], [qw(a b)]);
    $d-&gt;Seen({'*c' =&gt; $c});            # stash a ref without printing it
    $d-&gt;Indent(3);
    print $d-&gt;Dump;
    $d-&gt;Reset-&gt;Purity(0);              # empty the seen cache
    print join "----\n", $d-&gt;Dump;


    ########
    # persistence
    ########

    package Foo;
    sub new { bless { state =&gt; 'awake' }, shift }
    sub Freeze {
        my $s = shift;
	print STDERR "preparing to sleep\n";
	$s-&gt;{state} = 'asleep';
	return bless $s, 'Foo::ZZZ';
    }

    package Foo::ZZZ;
    sub Thaw {
        my $s = shift;
	print STDERR "waking up\n";
	$s-&gt;{state} = 'awake';
	return bless $s, 'Foo';
    }

    package Foo;
    use Data::Dumper;
    $a = Foo-&gt;new;
    $b = Data::Dumper-&gt;new([$a], ['c']);
    $b-&gt;Freezer('Freeze');
    $b-&gt;Toaster('Thaw');
    $c = $b-&gt;Dump;
    print $c;
    $d = eval $c;
    print Data::Dumper-&gt;Dump([$d], ['d']);


    ########
    # symbol substitution (useful for recreating CODE refs)
    ########

    sub foo { print "foo speaking\n" }
    *other = \&amp;foo;
    $bar = [ \&amp;other ];
    $d = Data::Dumper-&gt;new([\&amp;other,$bar],['*other','bar']);
    $d-&gt;Seen({ '*foo' =&gt; \&amp;foo });
    print $d-&gt;Dump;


=head1 BUGS

Due to limitations of Perl subroutine call semantics, you cannot pass an
array or hash.  Prepend it with a C&lt;\&gt; to pass its reference instead.  This
will be remedied in time, with the arrival of prototypes in later versions
of Perl.  For now, you need to use the extended usage form, and prepend the
name with a C&lt;*&gt; to output it as a hash or array.

C&lt;Data::Dumper&gt; cheats with CODE references.  If a code reference is
encountered in the structure being processed, an anonymous subroutine that
contains the string '"DUMMY"' will be inserted in its place, and a warning
will be printed if C&lt;Purity&gt; is set.  You can C&lt;eval&gt; the result, but bear
in mind that the anonymous sub that gets created is just a placeholder.
Someday, perl will have a switch to cache-on-demand the string
representation of a compiled piece of code, I hope.  If you have prior
knowledge of all the code refs that your data structures are likely
to have, you can use the C&lt;Seen&gt; method to pre-seed the internal reference
table and make the dumped output point to them, instead.  See L&lt;EXAMPLES&gt;
above.

The C&lt;Useqq&gt; flag makes Dump() run slower, since the XSUB implementation
does not support it.

SCALAR objects have the weirdest looking C&lt;bless&gt; workaround.


=head1 AUTHOR

Gurusamy Sarathy        gsar@activestate.com

Copyright (c) 1996-98 Gurusamy Sarathy. All rights reserved.
This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.


=head1 VERSION

Version 2.11   (unreleased)

=head1 SEE ALSO

perl(1)

=cut
</pre></body></html>